resume/flake.nix

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    systems.url = "github:nix-systems/default";
  };

  outputs = {
    self,
    systems,
    nixpkgs,
    ...
  } @ inputs: let
    eachSystem = f:
      nixpkgs.lib.genAttrs (import systems) (
        system:
          f nixpkgs.legacyPackages.${system}
      );
  in {
    packages = eachSystem (pkgs: {
      default = pkgs.stdenvNoCC.mkDerivation rec {
        name = "resume-latex";
        src = self;
        buildInputs = [
          pkgs.coreutils
          pkgs.findutils
          pkgs.texlive.combined.scheme-full
        ];
        buildPhase = ''
          export PATH="${pkgs.lib.makeBinPath buildInputs}"
          echo $PATH
          mkdir -p .cache/texmf-var
          env TEXMFHOME=.cache TEXMFVAR=.cache/texmf-var \
            latexmk -interaction=nonstopmode -f -pdf \
            resume.tex
        '';
        installPhase = ''
          mkdir -p $out
          cp resume.pdf $out/
          ln -s $out/resume.pdf $out/result
        '';
      };
    });

    hydraJobs = {
      build = self.packages."x86_64-linux".default;
      pdf = self.packages."x86_64-linux".default.outPath + "/result";
    };

    devShells = eachSystem (pkgs: {
      default = pkgs.mkShell {
        buildInputs = [
          pkgs.texlive.combined.scheme-full
          pkgs.texlab
          pkgs.termpdfpy
        ];
      };
    });
  };
}